強火で進め

このブログではプログラム関連の記事を中心に書いてます。

Sprite をグレースケールで描画するシェーダを作りました


まずはデフォルトの Sprite 用のシェーダを手に入れる為にこちらから最新のシェーダのソースコードを手に入れて作業しました。

始めは DefaultResourcesExtra フォルダの中の Sprites-Diffuse.shader を元に作業していたのですがこちらは上手く動作ませんでした。 DefaultResources フォルダの中にも同じ名前のファイルが有ったのでこちらを試してみた所バッチリ動作しました。

うーむ、 DefaultResourcesExtra フォルダと DefaultResources フォルダはどういうルールで分けられてるんだろ? もしご存知の方が居られましたらコメント欄にて教えて貰えて頂けましたら嬉しいです。

完成品

完成したシェーダの全コードはこちら。

Shader "Custom/Sprite-Grayscale" {
	Properties
	{
		[PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
		_Color ("Tint", Color) = (1,1,1,1)
		[MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
	}

	SubShader
	{
		Tags
		{ 
			"Queue"="Transparent" 
			"IgnoreProjector"="True" 
			"RenderType"="Transparent" 
			"PreviewType"="Plane"
			"CanUseSpriteAtlas"="True"
		}

		Cull Off
		Lighting Off
		ZWrite Off
		Fog { Mode Off }
		Blend SrcAlpha OneMinusSrcAlpha

		Pass
		{
		CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile DUMMY PIXELSNAP_ON
			#include "UnityCG.cginc"
			
			struct appdata_t
			{
				float4 vertex   : POSITION;
				float4 color    : COLOR;
				float2 texcoord : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex   : SV_POSITION;
				fixed4 color    : COLOR;
				half2 texcoord  : TEXCOORD0;
			};
			
			fixed4 _Color;

			v2f vert(appdata_t IN)
			{
				v2f OUT;
				OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
				OUT.texcoord = IN.texcoord;
				OUT.color = IN.color * _Color;
				#ifdef PIXELSNAP_ON
				OUT.vertex = UnityPixelSnap (OUT.vertex);
				#endif

				return OUT;
			}

			sampler2D _MainTex;

			fixed4 frag(v2f IN) : COLOR
			{
				half4 tex = tex2D(_MainTex, IN.texcoord) * IN.color;
				tex.rgb = dot(tex.rgb, float3(0.3, 0.59, 0.11));
				return tex;
			}
		ENDCG
		}
	}
}

変更箇所は以下の部分とシェーダ名だけです。

				return tex2D(_MainTex, IN.texcoord) * IN.color;

    ↓

				half4 tex = tex2D(_MainTex, IN.texcoord) * IN.color;
				tex.rgb = dot(tex.rgb, float3(0.3, 0.59, 0.11));
				return tex;

実際に使ってみたサンプルはこちら

参考情報

Unlit greyscale shader - Unity Answers
http://answers.unity3d.com/questions/343243/unlit-greyscale-shader.html